Send 메서드

탭스 메일러 서버로 PDF 보안 메일을 전달합니다.

형식

syntax

Set objError = objSecurePdfMail.Send()

objError

SecurePdfMailError 오브젝트. 메시지를 전달한 결과를 반환합니다.

objSecurePdfMail

SecurePdfMail 오브젝트

설명

PDF 보안 메일 메시지를 탭스 메일러 서버로 전달하기 위해서는 ServerName과 ServerPort를 지정해야 합니다. Send 메서드를 호출하면 메일 메시지 정보 데이터와 정의된 PDF 정보가 탭스 메일러 서버로 전송되며 서버에서는 PDF 문서 파일을 생성하고 MIME 메일 메시지를 구성하는 일련의 작업이 진행되므로 표준 SMTP를 구현하고 있는 일반 메일 서버로는 PDF 보안 메일을 처리할 수 없습니다.

전송 결과는 SecurePdfMailError 오브젝트로 반환되며 Type 및 Code 프로퍼티를 사용해 상세 오류 정보를 조회할 수 있습니다.

Send 메서드를 호출하면 추가된 수신자와 추가된 PDF 문서 파일 모두 초기화됩니다. 연결된 상태에서 다른 수신자에게 계속 메일을 보내기 위해서는 AddToAddr 메서드와 AddPdfDocument 메서드를 호출해 새롭게 수신자와 PDF 문서를 지정해야 합니다.

예제

ASP

Const SmtpErrorSuccess  = 0
Const SmtpErrorGeneral  = 1
Const SmtpErrorDNS      = 2
Const SmtpErrorNetwork  = 3
Const SmtpErrorSMTP     = 4

Set secMail = Server.CreateObject("TABSMailer4.SecurePdfMail")

secMail.ServerName = "127.0.0.1"
secMail.ServerPort = 6700

'기본 릴레이 캠페인으로 지정합니다.
secMail.CampaignID = "63E3F849-267F-4B6B-BC6E-496295D789B3"

secMail.FromAddress = "master@fromdomain.com"
secMail.AddToAddr "test@recvdomain.com", "테스트"
secMail.Subject = "테스트 메일 발송입니다."
secMail.Encoding = "base64"
secMail.Charset = "utf-8"
secMail.BodyHtml = secMail.LoadTextFromFile("C:\Template\template1.htm")

'PDF 문서를 정의합니다.
Set pdfDoc = Server.CreateObject("TABSMailer4.PdfDocument")
pdfDoc.FileName = "테스트.pdf"
pdfDoc.AddTocHtml secMail.LoadTextFromFile("C:\Template\template2.htm")
pdfDoc.OwnerPassword = "1234"
pdfDoc.UserPassword = "!@#$"

'PDF 문서를 메일에 첨부합니다.
secMail.AddPdfDocument pdfDoc

'탭스 메일러 서버와 연결해서 전달합니다.
Set result = secMail.Connect()
If result.Type = SmtpErrorSuccess Then
    Set result = secMail.Send()
    If result.Type = SmtpErrorSuccess Then
        Response.Write "메일이 올바르게 전달되었습니다."
    Else
        Response.Write "오류 종류:" & result.Type & "<br>오류 코드:" & result.Code & "<br>오류 설명:" & result.Description
    End If
    secMail.Close
Else
    Response.Write "오류 종류:" & result.Type & "<br>오류 코드:" & result.Code & "<br>오류 설명:" & result.Description
End If