FromString 메서드

JSON 텍스트를 해석해 JSON 오브젝트(또는 배열)를 반환합니다.

형식

syntax

Set newObjJson = objJson.FromString(jsonStr)

objJson

Required. JSON 오브젝트

newObjJson

Object. JSON 문자열을 해석한 후 새로 구성한 JSON 오브젝트를 반환합니다. JSON 문자열이 배열을 나타낼 경우 배열을 반환합니다.

jsonStr

String. JSON 형식 문자열을 지정합니다.

설명

JSON 문법 에 맞게 기술된 텍스트를 해석한 후 ASP에서 참조할 수 있는 오브젝트 또는 배열로 반환합니다. 반환된 JSON 오브젝트는 Item 프로퍼티를 사용해 값을 참조할 수 있으며, 반환된 배열을 인덱스 0부터 UBound(array) 까지 사용해 참조할 수 있습니다.

예제 1

JSON 문법으로 기술된 오브젝트를 해석한 후 프로퍼티 값을 참조하는 예제입니다.

ASP

Copy

Dim jsonStr, json, person
'JSON 텍스트
jsonStr = "{ ""이름"": ""홍길동"", ""나이"": 25, ""특기"": [""농구"", ""도술""], ""가족관계"": {""#"": 2, ""아버지"": ""홍판서"", ""어머니"": ""춘섬""} }"

Set json = Server.CreateObject("TABS.JSON")
Set person = json.FromString(jsonStr)

'JSON 오브젝트의 프로퍼티 값 참조
Response.Write person("이름")    '홍길동

'JSON 오브젝트 내에 정의된 배열 참조
Response.Write person("특기")(1)    '도술

'JSON 오브젝트 내에 정의된 또 다른 JSON 오브젝트 프로퍼티 참조
Response.Write person("가족관계")("어머니")    '춘섬

예제 2

JSON 문법으로 기술된 배열을 해석한 후 프로퍼티 값을 참조하는 예제입니다.

ASP

Copy

Dim jsonStr, json, vector
'JSON 텍스트
jsonStr = "[10, {""v"": 20}, [30, ""마흔""]]"

Set json = Server.CreateObject("TABS.JSON")
vector = json.FromString(jsonStr)

'배열 인덱스 0에 해당되는 값 참조
Response.Write vector(0)    '10

'배열 내에 정의된 JSON 오브젝트의 프로퍼티 값 참조
Response.Write vector(1)("v")   '20

'배열 내에 정의된 또 다른 배열 값 참조
Response.Write vector(2)(1)    '마흔