탭스 메일러 프로그래밍(ASP)

윈도우 서버에서 탭스 메일러로 메일을 전달하기 위해서는 탭스 메일러 SMTP 서버 컴포넌트를 사용해야 합니다. 탭스 메일러가 설치되어 있는 서버에는 해당 컴포넌트가 이미 설치되어 있지만 다른 컴퓨터에서 메일을 생성해 릴레이하고자 할 경우 아래와 같은 설치 작업이 필요합니다.

32비트 윈도우에 컴포넌트 설치 방법

COM/x86/TabsMailerCli.dll 파일을 선택합니다.
윈도우 서버의 C:\Windows\System32 폴더로 복사합니다.
명령창을 실행시켜 regsvr32 C:\Windows\System32\TabsMailerCli.dll을 실행해 레지스트리에 컴포넌트를 등록합니다.

64비트 윈도우에 64비트 컴포넌트 설치 방법

COM/x64/TabsMailerCli.dll 파일을 선택합니다.
윈도우 서버의 C:\Windows\System32 폴더로 복사합니다.
명령창을 실행시켜 regsvr32 C:\Windows\System32\TabsMailerCli.dll을 실행해 레지스트리에 컴포넌트를 등록합니다.

64비트 윈도우에 32비트 컴포넌트 설치 방법

64비트 윈도우에서 IIS 작업 프로세스를 32비트 모드로 운영할 필요가 있을 경우 다음과 같이 32비트 컴포넌트를 등록해야 탭스 메일러를 사용할 수 있습니다.

COM/x86/TabsMailerCli.dll 파일을 선택합니다.
윈도우 서버의 C:\Windows\SysWOW64 폴더로 복사합니다.
명령창을 실행시켜 32비트 COM을 등록할 수 있도록 C:\Windows\SysWOW64\regsvr32 C:\Windows\SysWOW64\TabsMailerCli.dll을 실행해 레지스트리에 컴포넌트를 등록합니다.

ASP에서 메일 발송

메일 메시지를 하나 생성해서 탭스 메일러의 기본 릴레이 캠페인으로 발송합니다.

SetTrace에 캠페인과 트레이스 URL을 지정하면 수신 확인이 자동으로 처리됩니다.

ASP

Copy

'상수 정의
Const TEXT_MSG = 0
Const HTML_MSG = 1
Const ENCODING_BASE64 = 0

Dim Mail

'메일 객체 생성
Set Mail = Server.CreateObject("TABS.Mailer3.1")

'탭스 메일러 서버 지정
Mail.ServerIp = "192.168.1.34"
Mail.ServerPort = 6700

Mail.BodyType = HTML_MSG
Mail.Encoding = ENCODING_BASE64
Mail.Charset = "euc-kr"
'발송자 지정
Mail.FromField "someone@tabslab.com", "보내는사람이름"
'수신자 지정
Mail.AddToAddr "test@tabslab.com", "받는사람이름"

Mail.Subject = "This is Test mail !!!"
Mail.Message = "<html><body>test message</body></html>"
Mail.AlterMessage = "HTML 메일 내용을 볼수 없으면, 이 메시지가 보일 것입니다."

'캠페인 정보 및 수신 확인 지정
Mail.SetTrace "{63E3F849-267F-4B6B-BC6E-496295D789B3}", "http://yourdomain/trace/mailread.ashx"

'메일 생성 후 전달
If Mail.Send() Then
    Response.Write "Ok"
Else
    Response.Write "Fail, " &Mail.LastError &", 오류 내용: " & Mail.GetLastErrorDesc
End If

'메일 객체 해제
Set Mail = Nothing

ASP에서 대량 메일 발송

데이터베이스에 저장되어 있는 다수의 수신자 정보를 읽은 후 메일을 탭스 메일러로 전달합니다. 탭스 메일러는 이 메시지를 받아서 기본 릴레이 캠페인으로 발송합니다.

SetTrace에 캠페인과 트레이스 URL을 지정하면 수신 확인이 자동으로 처리됩니다.

ASP

Copy

'상수 정의
Const TEXT_MSG = 0
Const HTML_MSG = 1
Const ENCODING_BASE64 = 0

Dim Mail

'메일 객체 생성
Set Mail = Server.CreateObject("TABS.Mailer3.1")

'탭스 메일러 서버 지정
Mail.ServerIp = "192.168.1.34"
Mail.ServerPort = 6700

Mail.BodyType = HTML_MSG
Mail.Encoding = ENCODING_BASE64
Mail.Charset = "urf-8"
'발송자 지정
Mail.FromField "someone@tabslab.com", "보내는사람이름"
Mail.Message = "<html><body>본문 메시지 입니다.</body></html>"
Mail.AlterMessage = "HTML 메일 내용을 볼수 없으면, 이 메시지가 보일 것입니다."

Dim conn, rs, count, btime
Set conn = Server.CreateObject("ADODB.COnnection")
conn.Open "PROVIDER=SQLOLEDB;Data Source=;Initial Catalog=User ID=;Password=;"
Set rs = conn.Execute("select email, name from dbo.members")
Do While Not rs.EOF
    Mail.ToAddr rs("email"), rs("name")
    Mail.Subject = rs("name") & "님 안녕하세요."

    '캠페인 정보 및 수신 확인 지정
    Mail.SetTrace "{63E3F849-267F-4B6B-BC6E-496295D789B3}", "http://yourdomain/trace/mailread.ashx"

    '메일 생성후 전달
    Mail.Send
    rs.MoveNext
Loop

rs.Close
conn.Close

'메일 객체 해제
Set Mail = Nothing

Note
전달해야할 메일의 수가 매우 많은 경우라면 TABS.Mailer3.1 컴포넌트 대신 데이터베이스를 통한 발송 방법 또는 SecurePdfMail 컴포넌트를 사용할 것을 권장합니다. 위 방법 보다 훨씬 빠른 속도로 메일을 탭스 메일러 서버로 전달할 수 있습니다.

탭스 메일러로 인증

안전한 메일 릴레이 환경을 구성을 위해 탭스 메일러 수신 부에 SMTP 인증이 설정되어 있다면 AuthId와 AuthPwd를 사용해 인증 계정과 암호를 지정합니다.

ASP

Copy

'메일 객체 생성
Set Mail = Server.CreateObject("TABS.Mailer3.1")

'탭스 메일러 서버 지정
Mail.ServerIp = "192.168.1.34"
Mail.ServerPort = 6700
Mail.AuthId = "tabsmailerauth"
Mail.AuthPwd = "******"

예약 발송 프로그래밍

ScheduleTime 프로퍼티를 지정된 시각에 발송이 시작되도록 예약할 수 있습니다. 해당 시각에 예약된 메일이 많을 경우 탭스 메일러 큐 알고리즘에 의해 예약 순으로 발송 시도됩니다.

ASP

Copy

'메일 객체 생성
Set Mail = Server.CreateObject("TABS.Mailer3.1")
Mail.ScheduleTime = "2012/07/15/01/00"