텍스트 효과 출력

TABS Image 오브젝트는 유용한 몇 가지 효과를 제공합니다. 투명 이미지에 텍스트를 그린 후 하이라이트 효과, 달궈진 효과, 3D 입체 효과를 줄 수 있습니다. 각 효과 별로 여러 파라미터가 존재하며 파라미터 값에 따라 다양한 모습으로 출력되므로 많은 효과를 제공할 수 있습니다.

텍스트 효과 출력

highlight-drop-shadow, glowing-hot, 3d-bevel 효과는 포토샵과 같은 전문 이미지 툴의 레이어 스타일과 유사한 것으로 투명이 존재하는 이미지에 대해 처리가 가능합니다. 투명 레이어에 텍스트를 쓴 후 여러가지 스타일로 장식하고 바탕 이미지 위에 합성하는 과정을 스크립트로 간단하게 표현해 효과를 처리합니다.

먼저 Create 메서드의 바탕색 파라미터에 "#00000000"을 지정해 투명 이미지를 생성합니다. 이 이미지 위에 DrawText를 호출해 텍스트를 출력합니다. 글자가 출력된 부분은 불투명이고 나머지 여백은 완전 투명인 이미지가 생성되었습니다.

SetEffect 메서드는 효과 종류에 따라 파라미터가 매우 가변적이므로 ImageParam 오브젝트를 사용해 파라미터를 표현합니다. 3d-bevel 효과는 3차원 효과로 light-degree에 빛 각도를 지정하고 drop-shadow에 그림자 정보를 지정하고 bevel-emboss에 3차원 출력 여부를 지정한 후 SetEffect를 호출하면 준비된 텍스트 이미지에 효과가 입혀지게 됩니다

효과가 적용된 이미지를 DrawImage 메서드를 사용해 바탕 이미지에 합성하면 효과가 적용된 텍스트가 출력된 이미지를 생성할 수 있습니다.

ASP

Copy

Dim Image, SubImage, Status, Width, Height, Param
Set Image = Server.CreateObject("TABSUpload4.Image")
Status = Image.Load("C:\images\sample.jpg")
If Status = Ok Then
    '텍스트를 출력할 투명 이미지를 생성합니다.
    Width = 400
    Height = 200
    Set SubImage = Server.CreateObject("TABSUpload4.Image")
    SubImage.Create Width, Height, "#00000000"

    SubImage.SetFont "궁서", 50, FontStyleBold
    SubImage.SetTextFormat StringAlignmentNear, True, False, False
    SubImage.DrawText "테스트 샘플 텍스트입니다.", "#ff0000", 0, 0, Width, Height

    Set Param = Server.CreateObject("TABSUpload4.ImageParam")
    Param.Add "light-degree", 135
    Param.Add "drop-shadow", True
    Param.Add "drop-shadow-size", 15
    Param.Add "drop-shadow-dist", 7
    Param.Add "bevel-emboss", true
    SubImage.SetEffect "3d-bevel", Param

    Image.DrawImage SubImage, 100, 100, 255
    Image.Save "C:\Images\texteffect.jpg", 100, True

    SubImage.Close
    Image.Close
    Set SubImage = Nothing
    Set Param = Nothing
Else
    Response.Write "이미지 파일을 열 수 없습니다. 오류 코드: " & Status
End If

Note
투명 이미지 위에 텍스트를 출력할 때 투명 성분이 포함되지 않게 완전 불투명으로 출력해야 합니다. 텍스트가 투명 성분을 가질 경우 효과가 올바르게 출력되지 않을 수 있습니다.