이미지 크기 변환 및 썸네일 생성

Image 컴포넌트는 이미지 크기 변환을 위해 Bicubic 또는 Bilinear 알고리즘을 사용하므로 고품질 이미지를 생성할 수 있습니다.

이미지 크기 변환

이미지 크기 변경을 위해서 Resize 메서드를 사용할 수 있습니다. 원본 이미지의 가로/세로 비율을 유지하면서 크기를 변경할 수 있고 가로, 세로를 별 개로 지정해 변경할 수도 있습니다.

ASP

Dim Image, Status
Set Image = Server.CreateObject("TABSUpload4.Image")
Status = Image.Load("C:\Images\sample1.jpg")
If Status = Ok Then
    '이미지 가로 크기가 640보다 클 경우 크기를 640으로 줄인다.
    If Image.Width > 640 Then
        Image.Resize 640, 0, ItpModeBicubic
        Image.Save "C:\Images\resize.jpg", 100, True
    End If
    Image.Close
Else
    Response.Write "이미지 파일을 열 수 없습니다. 오류 코드: " & Status
End If

썸네일 이미지 저장

썸네일 이미지는 로딩한 이미지를 축소하지 않고 별도의 SaveThumbnail 메서드를 호출해 파일로 직접 저장할 수 있습니다.

아래 스크립트는 가로/세로 비율을 유지하면서 가로 크기가 300 픽셀, 200 픽셀, 100 픽셀인 썸네일 이미지를 저장하는 예제입니다.

ASP

Copy

Dim Image, Status
Set Image = Server.CreateObject("TABSUpload4.Image")
Status = Image.Load("C:\Images\sample1.jpg")
If Status = Ok Then
    Image.SaveThumbnail "C:\Images\thumb300.jpg", 300, 0, 90
    Image.SaveThumbnail "C:\Images\thumb200.jpg", 200, 0, 90
    Image.SaveThumbnail "C:\Images\thumb100.jpg", 100, 0, 90
    Image.Close
Else
    Response.Write "이미지 파일을 열 수 없습니다. 오류 코드: " & Status
End If

피팅된 썸네일 이미지 저장

Thumbnail 메서드를 사용하면 Resize 메서드와 동일한 방식의 썸네일 생성과 더불어 부가적인 방식을 지원합니다. Fit 파라미터에 True 값을 지정할 경우 지정된 영역을 채우는 방식으로 썸네일을 생성할 수 있습니다.

아래 스크립트는 가로/세로 비율을 유지하면서 200x200 크기의 영역에 맞는 썸네일 이미지를 저장하는 예제입니다. 200x200 크기의 빈 이미지를 만들고 빈 이미지 내에 원본 이미지가 완전히 들어갈 수 있도록 크기를 조절합니다. 여백이 생길 경우 BgColor 파라미터에 지정된 색으로 여백을 채웁니다.

ASP

Copy

Dim Image, Status
Set Image = Server.CreateObject("TABSUpload4.Image")
Status = Image.Load("C:\Images\sample1.jpg")
If Status = Ok Then
    Image.Thumbnail 200, 200, ItpModeBicubic, True, True, "#ffffff", false
    Image.Save "C:\Images\thumb300.jpg", 90, False
    Image.Close
Else
    Response.Write "이미지 파일을 열 수 없습니다. 오류 코드: " & Status
End If

여백을 투명색으로 채우고자할 경우 #aarrggbb 형식으로 색상을 지정하며 alpha(투명) 값을 의미하는 aa에 00을 지정합니다. Save로 저장시 JPEG으로 저장할 경우 투명색이 표현되지 않으므로 투명색이 지원되는 PNG 형식으로 저장해야 합니다.